Warm tip: This article is reproduced from serverfault.com, please click
stata

Multiple choices in a choice data set

发布于 2020-12-08 22:41:34

The original data contains information on the consumerid and the cars they purchased.

clear
    input consumerid car    purchase
    6   American    1
    6   Japanese    0
    6   European    0
    7   American    0
    7   Japanese    0
    7   European    1
    7   Korean      1
end

Since this is a purchase data, the data set needs to be expanded in a way to depict the full choice set of cars every time a consumer made a purchase. The final data set should look like this (the screenshot taken from the Stata manual www.stata.com/manuals/cm.pdf on p. 97 in "Example 4: Multiple choices per case"):

enter image description here

I have generated several codes (shown below) to almost get me to where I need but I have trouble generating a single value of purchase=1 per consumerid-carnumber combination (i.e. due to the expansion, the purchase values are duplicated).

egen sumpurchase=total(purchase), by(id)
expand sumpurchase
bysort id car (purchase): gen carnumber=_n
Questioner
Olga
Viewed
0
分享
Wouter 2020-12-09 16:40:52

You could use reshape to get all combinations of consumerid/car per car bought. This example assumes that the sort order in the original dataset defines which car is carnumber 1, carnumber 2 etc.

* Example generated by -dataex-. To install: ssc install dataex
clear
input byte consumerid str8 car byte purchase
6 "American" 1
6 "Japanese" 0
6 "European" 0
7 "American" 0
7 "Japanese" 0
7 "European" 1
7 "Korean"   1
end

// Generate carnumber
bys consumerid: gen carnumber = cond(purchase != 0, sum(purchase), 0)

// To wide
reshape wide purchase, i(consumerid car) j(carnumber)

// Keep purchased cars only
drop purchase0

// Back to long
reshape long

// Drop if no cars purchased for consumerid/carnumber
bysort consumerid carnumber (purchase) : drop if missing(purchase[1])

// Replace missing with 0 for non-purchased cars
mvencode purchase, mv(0)

// Sort and see results
sort consumerid carnumber car
list, sepby(consumerid carnumber) abbr(14)

Results:

. list, sepby(consumerid carnumber) abbr(14)

     +----------------------------------------------+
     | consumerid        car   carnumber   purchase |
     |----------------------------------------------|
  1. |          6   American           1          1 |
  2. |          6   European           1          0 |
  3. |          6   Japanese           1          0 |
     |----------------------------------------------|
  4. |          7   American           1          0 |
  5. |          7   European           1          1 |
  6. |          7   Japanese           1          0 |
  7. |          7     Korean           1          0 |
     |----------------------------------------------|
  8. |          7   American           2          0 |
  9. |          7   European           2          0 |
 10. |          7   Japanese           2          0 |
 11. |          7     Korean           2          1 |
     +----------------------------------------------+
Olga 2020-12-10 13:15:35

This is a fantastic code, I just recreated it. Thank you Wouter.

热门帖子

1
这大约是独立开发的顶流了吧， v 友们怎么看
2
V 友们 今年刚需 需要买车 预算 20 出头 极氪 007 可以入吗
3
黑群和白群的差异，如何选择？
4
急收点发票（电脑、笔记本、硬盘、nas 、 iPad 、服务器、交通、鼠标、键盘）
5
自研摄影 App 胶片拾光，五一限时促销： 1 元购买终身会员
6
现在找工作怎么这么难
7
请问三星 S24 港版、美版，大家一般在哪儿购买？有没有渠道，介绍一下。
8
收一台 apple watch s7or s8 不锈钢（银钢）45mm，预算 2k 左右
9
私自把 Sim 卡数据写入 Esim，会被喝茶吗？
10
存款大概有 1.5%的利息差，我们能怎么做。。

热门github

1
A multi-platform library for OpenGL, OpenGL ES, Vulkan, window and input
2
Dev tool that writes scalable apps from scratch while the developer oversees the implementation
3
shadcn/ui, but for Svelte. ✨
4
The Python Risk Identification Tool for generative AI (PyRIT) is an open access automation framework to empower security professionals and machine learning engineers to proactively find risks in their generative AI systems.
5
Performance-portable, length-agnostic SIMD with runtime dispatch
6
ZK Credo
7
OpenCodeInterpreter: Integrating Code Generation with Execution and Refinement
8
Joplin - the secure note taking and to-do app with synchronisation capabilities for Windows, macOS, Linux, Android and iOS.
9
Mamba is a new state space model architecture showing promising performance on information-dense data such as language modeling, where previous subquadratic models fall short of Transformers. It is based on the line of progress on structured state space models, with an efficient hardware-aware design and implementation in the spirit of FlashAttention.
10
This repository contains System Design resources which are useful while preparing for interviews and learning Distributed Systems
11
Curso para aprender el lenguaje de programación Python desde cero y para principiantes. 75 clases, 37 horas en vídeo, código, proyectos y grupo de chat. Fundamentos, frontend, backend, testing, IA...
12
🎓 Path to a free self-taught education in Computer Science!
13
1️⃣🐝🏎️ The One Billion Row Challenge -- A fun exploration of how quickly 1B rows from a text file can be aggregated with Java
14
A collective list of free APIs
15
📚 Freely available programming books