第一种解决方案：你可以尝试对GNU中显示的示例进行以下跟踪，编写和测试awk。根据OP显示的示例，具有精确的15个浮点数：

awk -v lines=$(wc -l < Input_file) '
FNR==NR{
  if(FNR==lines){
    for(i=2;i<=NF;i++){ arr[i]=$i }
  }
  next
}
FNR<lines{
  for(i=2;i<=NF;i++){ $i=sprintf("%0.15f",(arr[i]?$i/arr[i]:"NaN")) }
  print
}
' Input_file  Input_file

第二种解决方案：如果你不希望浮点数成为特定点，请尝试执行以下操作。

awk -v lines=$(wc -l < Input_file) '
FNR==NR && FNR==lines{
  for(i=2;i<=NF;i++){ arr[i]=$i }
  next
}
FNR<lines && FNR!=NR{
  for(i=2;i<=NF;i++){ $i=(arr[i]?$i/arr[i]:"NaN") }
  print
}
' Input_file Input_file

OR（FNR==lines内部FNR==NR条件的放置条件）：

awk -v lines=$(wc -l < Input_file) '
FNR==NR{
  if(FNR==lines){
    for(i=2;i<=NF;i++){ arr[i]=$i }
  }
  next
}
FNR<lines{
  for(i=2;i<=NF;i++){ $i=(arr[i]?$i/arr[i]:"NaN") }
  print
}
' Input_file  Input_file

说明：在上面添加了详细说明。

awk -v lines=$(wc -l < Input_file) '         ##Starting awk program from here, creating lines which variable which has total number of lines in Input_file here.
FNR==NR{                                     ##Checking condition FNR==NR which will be TRUE when first time Input_file is being read.
  if(FNR==lines){                            ##Checking if FNR is equal to lines then do following.
    for(i=2;i<=NF;i++){ arr[i]=$i }          ##Traversing through all fields here of current line and creating an array arr with index of i and value of current field value.
  }
  next                                       ##next will skip all further statements from here.
}
FNR<lines{                                   ##Checking condition if current line number is lesser than lines, this will execute when 2nd time Input_file is being read.
  for(i=2;i<=NF;i++){ $i=sprintf("%0.15f",(arr[i]?$i/arr[i]:"NaN")) } ##Traversing through all fields here and saving value of divide of current field with arr current field value with 15 floating points into current field.
  print                                      ##Printing current line here.
}
' Input_file  Input_file                     ##Mentioning Input_file names here.