温馨提示:本文翻译自stackoverflow.com,查看原文请点击:java - How to execute a task before executing or building the subprojects in gradle?

java - 如何在gradle中执行或构建子项目之前执行任务?

发布于 2020-03-30 21:52:24

如何在gradle中执行或构建子项目之前执行任务?

build.gradle在根项目中具有以下内容的多项目构建

apply plugin: 'java'
apply plugin: 'com.google.protobuf'

protobuf {

   protoc {
    // Download from repositories
    artifact = 'com.google.protobuf:protoc:3.10.0'
   }

   plugins {
      grpc {
        artifact = 'io.grpc:protoc-gen-grpc-java:1.23.0'
      }
   }

   generateProtoTasks {
      ofSourceSet('main')*.plugins {
        grpc {}
      }
   }
}

tasks.withType(JavaCompile) {
  dependsOn 'protobuf'
}

allprojects {

}

subprojects {

}

我希望在编译任何子项目之前先执行protobuf任务,因为我的子项目取决于从protobuf任务生成的Java文件。那么我该如何实现呢?我不想在每个子项目中都有protobuf任务,而只想在根项目中一次但在编译子项目之前就执行它。

查看更多

提问者
user1870400
被浏览
31
kaushik 2020-02-06 11:19

我为此创建了一个示例项目。根项目称为“ protobuffer ”,它具有两个子项目,如下所示:

  • Java项目
  • 原型

' proto '项目包含java项目的proto文件。proto项目的build.gradle.kts文件如下:

import com.google.protobuf.gradle.*

plugins {
    id ("com.google.protobuf")
}

tasks.check { dependsOn("generateProto") }

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:3.6.1"
    }

    generatedFilesBaseDir = File(project(":java-project").projectDir.toString(), "src").toString()
}

dependencies {
    implementation("com.google.protobuf:protobuf-java:3.6.1")
}

根项目的build.gradle.kts文件如下:

import com.google.protobuf.gradle.GenerateProtoTask
plugins {
    java
    id ("com.google.protobuf") version ("0.8.8") apply false
}

allprojects {
    repositories {
        mavenCentral()
        maven {
            url = uri("https://plugins.gradle.org/m2/")
        }
    }
}

subprojects {
    apply(plugin="java")
    apply(plugin="idea")

    if (name != "proto") {
        tasks.withType<JavaCompile> {
            dependsOn(project(":proto").tasks.withType<GenerateProtoTask>())
        }
    }
}

根项目中settings.gradle.kts文件如下:

rootProject.name = "protobuffer"
include("proto")
include("java-project")


pluginManagement {
    repositories {
        mavenLocal()
        maven {
            url = uri("https://plugins.gradle.org/m2/")
        }
    }

    resolutionStrategy {
        eachPlugin {
            if (requested.id.id == "com.google.protobuf") {
                useModule("com.google.protobuf:protobuf-gradle-plugin:${requested.version}")
            }
        }
    }
}